『Math.random() を使ってランダムに色を変える方法』で利用したBall.asを今回も使ってステージにボールを配置します。
X軸はステージの1/5の位置に配置し、Y軸をステージの真ん中に配置させます。（サイズ50と青色を指定）

//Ball.asを読み込み
var ball:Ball = new Ball(50, 0x0000ff);
addChild(ball);
ball.x = stage.stageWidth / 5;
ball.y = stage.stageHeight / 2;

これでステージにボールが表示されるようになったと思いますので、次にボールを動かすスクリプトを書きます。
今までやってきたムービークリップの動かし方にさらに加速度のプログラムを足します。

//イベントリスナー
ball.addEventListener(Event.ENTER_FRAME, loop);

function loop(event:Event):void{
	ball.x += 1;
}

上記が従来ムービークリップのX軸に1を足して動かす方法ですが、下記は1の変わりに変数（vx)を用いてX軸の数値に置き換え、さらに加速変数（ax)をフレームが読み込まれる度に足して変数vxの数値を増やしていく感じになります。

//イベントリスナー
ball.addEventListener(Event.ENTER_FRAME, loop);

function loop(event:Event):void{
	vx += ax;
	ball.x += vx;
}

こうすることにより、ボールがどんどん加速しているように見えます。
今回は加速度を1に設定しましたが、数値を変えれば加速度を調整できます。
この加速度は色々な場面でも使うことができるので、徐々に何かをしたい時になどに使うと便利です。

//Ball.asを読み込み
var ball:Ball = new Ball(50, 0x0000ff);
//インスタンスプロパティー
var vx:Number = 0; //初期値
var ax:Number = 1; //加速度

addChild(ball);
ball.x = stage.stageWidth / 5;
ball.y = stage.stageHeight / 2;
//イベントリスナー
ball.addEventListener(Event.ENTER_FRAME, loop);

function loop(event:Event):void{
	vx += ax;
	ball.x += vx;
}

ボールがなくなってたらもう一度更新して下さい。

関連する投稿

• クラス参照でステージにムービークリップを配置[3-1] (0)
• カスタムクラスでステージにムービークリップを配置[3-3] (0)
• クラス参照でステージにムービークリップを配置[3-2] (0)
• Tweenクラスでムービークリップをトゥイーンさせる[3-4] (0)
• ムービークリップをボタンとして使う[2-4] (0)

Flashのライブラリーに画像を置かずに、外部から画像がある場所を指定して画像を読み込みます。
こうすることにより、画像のみ変更する時に、イチイチFlashを編集しなくて済むので、非常に有効的な方法だと思います。

まず表示させたい画像をフォルダにまとめて、swfファイルと同じ階層に配置します。（今回は3枚の外部画像を読み込んでみたいと思います。）

画像の用意ができたら、アクションスクリプトを書いていきます。
Actionscript3.0からなんですが、外部から画像を読み込むときにLoaderクラスと言う便利な機能が追加されました。
そこでnew演算子を使って、変数myLoaderに新しくLoaderクラスを読み込ませます。しかしこれだけでは、画像がどこにあるのか分からないので画像がある場所をURLRquestクラスを使って指定し、変数ImgUrlに置き換えてからmyLoaderにImgUrlをロードさせるカラクリになります。
あとはaddChilで表示させます。

//Loaderオブジェクト生成
var myLoader:Loader = new Loader();
//ファイルパス読み込み
var ImgUrl:URLRequest = new URLRequest("images/img1.jpg");
//画像読み込み
myLoader.load(ImgUrl);
addChild(myLoader);

しかし今回は複数画像を読み込むようにする為、画像の場所を指定したパスを配列に格納してから使うことにします。
さらに読み込んだ画像ごとにy軸の位置をずらします。

//配列
var url:Array = new Array();
url[0] = "images/img1.jpg";
url[1] = "images/img2.jpg";
url[2] = "images/img3.jpg";

for (var i:int = 0; i < 3; i++) {
	//Loaderオブジェクト生成
	var myLoader:Loader = new Loader();
	//ファイルパス読み込み
	var ImgUrl:URLRequest = new URLRequest(url[i]);

	//画像読み込み
	myLoader.load(ImgUrl);
	myLoader.y = 60 * i;
	addChild(myLoader);

}

関連する投稿

• クラス参照でステージにムービークリップを配置[3-2] (0)
• ムービークリップを徐々に加速させる[3-7] (0)
• ムービークリップをボタンとして使う[2-4] (0)
• ムービークリップをボタンとして使う[2-3] (0)
• ボタンに連動してムービークリップの表示を変える[2-7] (0)

[3-3]でステージに配置したムービークリップにトゥイーンモーションを指定してます。

タイムライン上にあるアクションスクリプトに、まずTweenクラスとeasingクラスをインポートさせ、使えるようにします。

//クラスのインポート
import fl.transitions.Tween;
import fl.transitions.easing.*;

Tweenクラスに関しては、もっと奥が深いので今回は取り合えず簡単に使えるやり方にします。
詳しくはもっと勉強してからと言うことで…

[3-3]でカクスタムクラスを使ってステージ上にムービークリップを配置してますので、さらにTweenクラス用のアクションスクリプトを追記します。

// モーション設定
var mcTween:Tween;
mcTween = new Tween(my_mc, "y", Bounce.easeOut, 0, (stage.stageHeight - my_mc.height/2), 5, true);

変数mcTweenをTweenクラスを指定して宣言し、new演算子でTweenクラスでトゥイーンさせる処理を書きます。
順番としては
①トゥイーンさせるインスタンス名
②変化させたいプロパティ
③アニメーションの種類
④開始値
⑤終了値
⑥継続時間
⑦継続時間の単位
になります。
アニメーションの種類に関しては、あとでまとめます。

今回はムービークリップのY軸にイージング終了時にバンドさせる処理としてます。
カスタムクラスでステージ配置されたムービークリップは初期表示位置x軸はステージ幅の1/10で表示されるが、Y軸に関してはトゥイーンで0からステージの高さ（ステージいっぱい）に移動して、終了時にバウンドするせる感じになります。

//クラスのインポート
import fl.transitions.Tween;
import fl.transitions.easing.*;

// Ballクラスからインスタンスを作る
var my_mc:Ball = new Ball();
addChild(my_mc);
my_mc.x = stage.stageWidth / 10;

// モーション設定
var mcTween:Tween;
mcTween = new Tween(my_mc, "y", Bounce.easeOut, 0, (stage.stageHeight - my_mc.height/2), 5, true);

asファイルに関しては[3-3]と同じになりますので、省略します。

アニメーションの種類

イージンの種類

関連する投稿

• ムービークリップを徐々に加速させる[3-7] (0)
• クラス参照でステージにムービークリップを配置[3-2] (0)
• クラス参照でステージにムービークリップを配置[3-1] (0)
• カスタムクラスでステージにムービークリップを配置[3-3] (0)
• ムービークリップをボタンとして使う[2-4] (0)

いままでは、タイムライン上（flaファイル）に直接アクションスクリプトを記述してきましたが、今回はasファイル（カスタムクラス）を使って外部からアクションスクリプトを書いていきます。

カスタムクラスを使って外部からアクションスクリプトを書く場合には、いくつかルールがあります。
パッケージ名、クラス名、インスタンスの変数、コンストラクタの定義、メソッドの定義を条件に応じて記述しなくてはなりません。

//パッケージ名
package {
	//インポートするクラス
	import flash.display.MovieClip;
	import flash.events.Event;
	//クラス定義
	public class asファイル名と同じ {
		//変数の宣言
		//コンストラクタの定義
		//メソッド定義
	}
}

パッケージ名とは、クラスが属するパッケージを示します。
パッケージ名を省略すると、デフォルトパッケージと見なされます。その場合はasファイルはflaファイルと同じ階層に置かなくてはなりません。

クラス名とは、クラスの名前ですが、アクションスクリプトでは、このクラス名とasファイル名が同じにする必要があります。

インスタンスの変数とは、クラスで使う変数となりますが、外部のクラスから変数にプロパティとしてアクセスするには、publicを指定しなくてなりません。

コンストラクタの定義とは、実行させたいプログラムを動かす為の定義となります。
これもインスタンスの変数と同様にpublicが必要になります。

メソッドの定義とは、簡単に言うと実行するプウログラム本体になります。

flaファイルのステージ配置したいムービークリップをライブラリーに用意して、リンケージ名を付けます。（今回はBallにしました）
さらにasファイルにアクションスクリプトを書いていきます。

package {
	// インポート
	import flash.display.MovieClip;
	import flash.events.Event;

	public class Ball extends MovieClip {
		// 変数の宣言
		public var myXspeed:Number = 5; // X軸方向の速度
		public var myCicle:Number = 10;  //ボールの回転

		// コンストラクタの定義
		public function Ball() {
			this.addEventListener(Event.ENTER_FRAME, enterF);
		}

		// メソッドの定義（ボールを動かす関数）
		private function enterF(event:Event):void {
			this.x += myXspeed;
			this.rotation += myCicle;
			if(this.x < 50 || this.x > 500){
				myXspeed *= -1;
				myCicle *= -1;
			}
		}
	}
}

今回は同じ階層にasファイルを置くため、パッケージ名は付けてません。
クラス名を先程リンケージで付けた名前のBallとし、保存するファイル名もBall.asにします。

次にflaファイルにBall.asを読み込まして、ムービークリップをステージに配置する為に、タイムラインにアクションスクリプトを書きます。

// Ballクラスからインスタンスを作る
var ball_mc:Ball = new Ball();
addChild(ball_mc);
ball_mc.x = stage.stageWidth / 2;
ball_mc.y = stage.stageHeight / 2;

ball_mc.xとball_mc.yで初期表示位置を指定しています。

ムービークリップの動きは[1-5]同じになりますが、アクションスクリプトは外部から読み込んだ状態になっています。

関連する投稿

• ムービークリップを徐々に加速させる[3-7] (0)
• クラス参照でステージにムービークリップを配置[3-1] (0)
• クラス参照でステージにムービークリップを配置[3-2] (0)
• Tweenクラスでムービークリップをトゥイーンさせる[3-4] (0)
• ムービークリップをボタンとして使う[2-4] (0)

あらかじめライブラリーに表示させたいムービークリップを用意し、プロパティーでリンケージのクラス名に順番を付けて用意します。（例：img_mc1）

用意できたら、ムービークリップの順番を配列に置き換えます。

//配列
var myImg:Array = new Array();
myImg[0] = "img_mc1"
myImg[1] = "img_mc2"
myImg[2] = "img_mc3"

次にランダムで表示させる為のプログラムを用意します。
ランダムで表示させる為には、変数NoにMath.randomを使って、配列の数をランダムに置き換えまる感じになります。

var No = Math.floor(Math.random()* myImg.length);

さらに、ランダムで置き換えられた変数Noを使って、ステージ上にムービークリップを表示させます。

var class_str:String = myImg[No];
var myClass:Class = Class(getDefinitionByName(class_str));
var img:MovieClip = new myClass();
addChild(img);

ランダムで変数Noを決めて、その変数Noの該当する配列の文字列を、getDefinitionByNameでクラス定義しムービークリップとして変数imgに置き換えaddchildでステージ表示させるカラクリになります。

//配列
var myImg:Array = new Array();
myImg[0] = "img_mc1"
myImg[1] = "img_mc2"
myImg[2] = "img_mc3"

//変数
var No = Math.floor(Math.random()* myImg.length);
var class_str:String = myImg[No];
var myClass:Class = Class(getDefinitionByName(class_str));
var img:MovieClip = new myClass();
addChild(img);
img.x = stage.stageWidth / 2;
img.y = stage.stageHeight / 2;

ステージの中心に表示させる為にstage.stageWidth / 2とstage.stageHeight / 2で表示位置を指定してます。

関連する投稿

• ムービークリップを徐々に加速させる[3-7] (0)
• クラス参照でステージにムービークリップを配置[3-1] (0)
• カスタムクラスでステージにムービークリップを配置[3-3] (0)
• Tweenクラスでムービークリップをトゥイーンさせる[3-4] (0)
• Math.random() を使ってランダムに色を変える方法 (0)

あらかじめライブラリーに表示させたいムービークリップを用意し、プロパティーでリンケージのクラス名を付けます。（例：ball_mc）

new演算子を使ってムービークリップballに置き換え、addChildを使ってステージにムービークリップを配置します。

//ステージに配置
var ball:MovieClip = new ball_mc();
addChild(ball);
ball.x = stage.stageWidth / 2;
ball.y = stage.stageHeight / 2;

初期表示位置（スタート位置）をステージの真ん中に設定しました。

[1-5]で使用した反復運動するアクションスクリプトを使いムービークリップを動かします。

//ステージに配置
var ball:MovieClip = new ball_mc();
addChild(ball);
ball.x = stage.stageWidth / 2;
ball.y = stage.stageHeight / 2;

var speedx:Number = 5;  //スピード
var cicle:Number = 10;  //回転
var mcWidth:Number = ball.width / 2;  //インスタンスの幅
var stageL:Number = 0 + mcWidth;  //幅の最小値
var stageR:Number = stage.stageWidth - mcWidth;  //幅の最大値

ball.addEventListener(Event.ENTER_FRAME,movieBall);  //イベントリスナー登録

//ballのプログラム関数
function movieBall(event:Event):void {
	ball.x += speedx;
	ball.rotation += cicle;
	if (ball.x < stageL || ball.x > stageR) {
		speedx *= -1;
		cicle *= -1;
	}
}

関連する投稿

• ムービークリップを徐々に加速させる[3-7] (0)
• カスタムクラスでステージにムービークリップを配置[3-3] (0)
• クラス参照でステージにムービークリップを配置[3-2] (0)
• Tweenクラスでムービークリップをトゥイーンさせる[3-4] (0)
• ムービークリップをボタンとして使う[2-4] (0)